home *** CD-ROM | disk | FTP | other *** search
/ FM Towns: Free Software Collection 9 / FM Towns Free Software Collection 9.iso / t_os / tool / cw3 / cw3.bas next >
BASIC Source File  |  1994-11-16  |  28KB  |  853 lines
  1. 1000 '##  モールスを覚えちゃおう！     ##
  2. 1010 '##    HI-CCC   製作者: 尋燐･ルナ ##
  3. 1020 '##          V2.04    1993/07/28  ##  フリコレ６
  4. 1030 '##          V2.05    1993/08/30  ##  printer･音声出力 対応
  5. 1040 '##          V3.02    1994/07/07  ##  １級対応
  6. 1050 :
  7. 1060  DEFSTR A
  8. 1070  RANDOMIZE TIME
  9. 1080  TEST=0  :'制作用
  10. 1090 :
  11. 1100  GOSUB *初期化
  12. 1110  GOSUB *項目設定
  13. 1120  GOSUB *符号セット
  14. 1130  GOSUB *スタータ
  15. 1140 *やり直し
  16. 1150  GOSUB *画面
  17. 1160  GOSUB *BACK
  18. 1170  GOSUB *入力
  19. 1180  GOSUB *WINDO2
  20. 1190  GOSUB *実行
  21. 1200 GOTO  *やり直し
  22. 1210 :
  23. 1220 *終了
  24. 1230 END
  25. 1240 :
  26. 1250 '----ＳＵＢ----
  27. 1260 *初期化
  28. 1270  SCREEN@ 0  :CLS :PALETTE
  29. 1280  DIM AK(120) :'見本符号リスト
  30. 1290  DIM AL(250) :'解答符号リスト
  31. 1300  MAX=0
  32. 1310  OTO=700     :'音程
  33. 1320  SPEED=12    :'速さ
  34. 1330  CLASS=2     :'級
  35. 1340  DIM ACLASS(4)  :'級名
  36. 1350   ACLASS(0)="１級和文" :ACLASS(1)="１級欧文"
  37. 1360   ACLASS(2)="２級欧文" :ACLASS(3)="３級欧文" 
  38. 1370   ACLASS(4)="特殊記号"
  39. 1380  ON KEY(10) GOSUB *強制終了
  40. 1390 RETURN
  41. 1400 :
  42. 1410 *項目設定
  43. 1420 'ウインド1
  44. 1430  W1C=20       :'##ウインド1の最大項目数
  45. 1440  DIM AW(W1C)  :'##項目名
  46. 1450  DIM SW(W1C)  :'##設定1
  47. 1460  DIM AW1(W1C) :'##設定2
  48. 1470   RESTORE *設定DATA :I=0
  49. 1480    READ AW(I),SW(I),AW1(I)
  50. 1490    IF AW(I)<>"" THEN I=I+1 :GOTO 1480 ELSE W1C=I-1
  51. 1500 'ウインド2
  52. 1510  DIM AH(W1C+2)   :'##HELPメッセージ
  53. 1520  RESTORE *ＨDATA :FOR I=0 TO W1C+2 :READ AH(I) :NEXT
  54. 1530 RETURN
  55. 1540 :
  56. 1550 '--------
  57. 1560 *画面
  58. 1570  SCREEN@ 0 :CLS :WIDTH 80,20
  59. 1580  PALETTE 9,[100,100,120]
  60. 1590  PALETTE 10,[180,180,180]
  61. 1600  PALETTE 11,[0,0,120]
  62. 1610  LINE (0,0)-(639,479),PSET,%9,BF
  63. 1620  SYMBOL (30,10),"モールスを覚えちゃおう！",2,1,6,,,15
  64. 1630  SYMBOL (150,32),"スペシャル",1,1,%2,,,1,2
  65. 1640  SYMBOL (350,30),"V3.02",1,1,5,,,1,2
  66. 1650  SYMBOL (450,10),"ＪＧ０ＱＫＲ",1,1,4,,,7
  67. 1660  SYMBOL (450,30),"製作者: 尋燐･ルナ",1,1,4,,,1
  68. 1670  LINE (35,40)-(435,40),PSET,%11
  69. 1680  CONNECT (435,5)-(405,60)-(620,60)-(610,50)-(610,70),%11
  70. 1690  GOSUB *WIND1
  71. 1700  X0=400 :Y0=105 :X1=600 :Y1=244 :GOSUB *ウインド
  72. 1710  COLOR 4 :LOCATE 57,4 :PRINT "メッセージ"
  73. 1720 RETURN
  74. 1730 :
  75. 1740 *ウインド
  76. 1750  CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
  77. 1760  CONNECT (X0-1,Y1)-(X0-1,Y0-1)-(X1+1,Y0-1),%10
  78. 1770  CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0),0
  79. 1780  CONNECT (X0-1,Y1+1)-(X1+1,Y1+1)-(X1+1,Y0-1),0
  80. 1790  X0=X0+30 :X1=X0+140 :Y0=Y0-14 :Y1=Y0+24
  81. 1800  LINE (X0,Y0)-(X1,Y1),PSET,%9,BF
  82. 1810  CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
  83. 1820  CONNECT (X0-1,Y1-12)-(X0-1,Y0+1)-(X1+1,Y0+1),%10
  84. 1830  CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0+1),0
  85. 1840  CONNECT (X1+1,Y1-12)-(X1+1,Y0+1),0
  86. 1850 RETURN
  87. 1860 :
  88. 1870 *WIND1  :'メイン窓
  89. 1880  X0=50 :Y0=82 :X1=350 :Y1=120+25*W1C :GOSUB *ウインド
  90. 1890  COLOR 4 :LOCATE 13,3 :PRINT AW(0)
  91. 1900  FOR I=1 TO W1C
  92. 1910   X0=60 :Y0=93+I*24 :X1=190 :Y1=90+(I+1)*24
  93. 1920   CONNECT (X0,Y1)-(X0,Y0)-(X1,Y0),%10
  94. 1930   CONNECT (X0,Y1)-(X1,Y1)-(X1,Y0),0
  95. 1940   COLOR 6 :LOCATE 9,4+I :PRINT AW(I);
  96. 1950   IF SW(I)=-2 THEN LOCATE 27,4+I :PRINT SPEED :GOTO 2000
  97. 1960   IF SW(I)=-4 THEN LOCATE 27,4+I :PRINT ACLASS(CLASS) :GOTO 2000
  98. 1970   IF SW(I)=-5 THEN LOCATE 31-LEN(STR$(OTO)),4+I :PRINT OTO :GOTO 2000
  99. 1980   IF SW(I)<0  THEN LOCATE 27,4+I :PRINT AW1(I); 
  100. 1990   IF SW(I)>=0 THEN LOCATE 25,4+I :PRINT "   する   しない" 
  101. 2000   GOSUB *SW
  102. 2010  NEXT
  103. 2020 RETURN
  104. 2030 :
  105. 2040 *SW  :'スイッチの窓
  106. 2050  IF SW(I)>=0 THEN 2160
  107. 2060  IF SW(I)=-3 OR SW(I)>1 THEN RETURN
  108. 2070  IX0=205 :IY0=93+I*24 :IY1=90+(I+1)*24
  109. 2080  IF SW(I)=-1  THEN IX1=IX0+120
  110. 2090  IF SW(I)=-2  THEN IX1=IX0+50
  111. 2100  IF SW(I)=-4  THEN IX1=IX0+85
  112. 2110  IF SW(I)=-5  THEN IX1=IX0+50
  113. 2120  I0=0 :I1=10
  114. 2130  CONNECT (IX0,IY1)-(IX0,IY0)-(IX1,IY0),%I0 :CONNECT (IX0,IY1)-(IX1,IY1)-(IX1,IY0),%I1
  115. 2140 RETURN
  116. 2150 'はい･いいえ の窓
  117. 2160  IX0=210 :IX1=274 :IY0=93+I*24 :IY1=90+(I+1)*24 
  118. 2170  IF SW(I) THEN 2230
  119. 2180  CONNECT (IX1,IY1)-(IX1,IY0)-(IX1+60,IY0),0 
  120. 2190  CONNECT (IX1,IY1)-(IX1+60,IY1)-(IX1+60,IY0),%10
  121. 2200  CONNECT (IX0,IY1)-(IX0,IY0)-(IX0+57,IY0),%9 
  122. 2210  CONNECT (IX0,IY1)-(IX0+57,IY1)-(IX0+57,IY0),%9
  123. 2220 RETURN
  124. 2230 :CONNECT (IX0,IY1)-(IX0,IY0)-(IX0+57,IY0),0 
  125. 2240  CONNECT (IX0,IY1)-(IX0+57,IY1)-(IX0+57,IY0),%10
  126. 2250  CONNECT (IX1,IY1)-(IX1,IY0)-(IX1+60,IY0),%9 
  127. 2260  CONNECT (IX1,IY1)-(IX1+60,IY1)-(IX1+60,IY0),%9
  128. 2270 RETURN
  129. 2280 :
  130. 2290 *設定DATA
  131. 2300  DATA "各 種 設 定"   ,-3,""
  132. 2310  DATA "本番モード"    , 0,""
  133. 2320  DATA "試験難易度"    ,-4,""
  134. 2330  DATA "スピード"      ,-2,""
  135. 2340  DATA "･速度テスト"   , 0,""
  136. 2350  DATA "･ランダム"     , 0,""
  137. 2360  DATA "･ウエイト"     , 0,""
  138. 2370  DATA "･５文字暗文"   , 0,""
  139. 2380  DATA "･解答同時表示" , 0,""
  140. 2390  DATA "･ﾓｰﾙｽ同時表示" , 0,""
  141. 2400  DATA "･数字付加"     , 0,""
  142. 2410  DATA "･記号付加"     , 0,""
  143. 2420  DATA "音程"          ,-5,""
  144. 2430  DATA "解答を印刷する", 0,""
  145. 2440  DATA "音声メッセージ", 0,""
  146. 2450  DATA "",0,""
  147. 2460 :
  148. 2470 *WINDO2  :'サブメニュー
  149. 2480  I=0
  150. 2490  GOSUB *W2
  151. 2500  PRINT " "
  152. 2510  A=INPUT$(1)
  153. 2520   IF A=CHR$(27) THEN *終了
  154. 2530   IF A=CHR$(24) THEN RETURN *やり直し
  155. 2540   IF A="*" THEN GOSUB *OMAKE :RETURN *やり直し
  156. 2550   IF A="/" THEN GOSUB *見本 :RETURN *やり直し
  157. 2560   IF A<>CHR$(13) THEN 2510
  158. 2570 RETURN
  159. 2580 :
  160. 2590 *WIND2
  161. 2600  I=NO
  162. 2610  GOSUB *W2
  163. 2620  PRINT "<'Retキー'で設定終了>"
  164. 2630 RETURN
  165. 2640 :
  166. 2650 *W2
  167. 2660  COLOR 7
  168. 2670  A=AH(I)+SPACE$(50)
  169. 2680   FOR I0=1 TO 5
  170. 2690    LOCATE 52,4+I0
  171. 2700    PRINT MID$(A,I0*22-21,22)
  172. 2710   NEXT
  173. 2720  COLOR 5 :LOCATE 51,9 
  174. 2730 RETURN
  175. 2740 :
  176. 2750 *ＨDATA
  177. 2760 DATA "Ret････ 試験を開始するESC････ 終了する      取消･･･ 設定をし直す　＊ ････ おまけ        ／ ････モールス見本"   
  178. 2770 DATA "形式（本番用・練習用）を選んでください。　　練習では一通りやるだけです。"
  179. 2780 DATA "1･2･3級 和/欧文 対応です。練習モード時の級は意味を成しません。実戦用に記号モードも有り！"
  180. 2790 DATA "スピードを←→で選んでください。数字が小さくなるほど速くなります。"
  181. 2800 DATA "スピードをチェックします。級を選択後実行します。１分が試験速度。少し速めが良い。"
  182. 2810 DATA "Ａ－Ｚ（ア－ン）までランダムに実行するときは'する'を選択。最初は順番で覚えましょう！"
  183. 2820 DATA "１文字づつウエイトを掛けるときには'する'を選択。                  練習モードの時のみ。"
  184. 2830 DATA "ランダム５文字毎にスペースが入る。スペースの感覚も結構だいじです。"
  185. 2840 DATA "モールス信号と同時に解答（英語・日本語）も表示する。              練習モードの時のみ。"
  186. 2850 DATA "モールス信号と同時に解答（モールス記号）も表示する。              練習モードの時のみ。"
  187. 2860 DATA "数字も練習するかどうかの選択です。１／２級では出題されますので練習した方が賢明です。"
  188. 2870 DATA "記号も練習するかどうかの選択です。実戦及び１級では練習した方が賢明です。"
  189. 2880 DATA "モールスの音程を決めます。６５０前後が良いと思いますが．．．．"
  190. 2890 DATA "解答を印刷します。テープに録音して練習するのに便利かと思います。"
  191. 2900 DATA "始めと終わりに音声でのアナウンスが有ります。より実戦的かと。テープ録音の頭出しにも便利！"
  192. 2910 DATA ""
  193. 2920 :
  194. 2930 '-----
  195. 2940 *入力
  196. 2950  NO=1 :ONO=2
  197. 2960 *IN0
  198. 2970  IF NO<1 THEN NO=W1C
  199. 2980  IF NO>W1C THEN NO=1
  200. 2990  GOSUB *WIND2
  201. 3000  LOCATE 9,4+ONO :COLOR 6 :PRINT AW(ONO)
  202. 3010  LOCATE 9,4+NO :COLOR 5 :PRINT AW(NO)
  203. 3020  ONO=NO
  204. 3030 *IN1
  205. 3040 A=INPUT$(1)
  206. 3050  IF A=CHR$(13) THEN RETURN
  207. 3060  IF A=CHR$(&H1F) THEN NO=NO+1 :GOTO *IN0
  208. 3070  IF A=CHR$(&H1E) THEN NO=NO-1 :GOTO *IN0
  209. 3080  IF SW(NO)=-5 THEN *IN6  '##音程
  210. 3090  IF SW(NO)=-4 THEN *IN5  '##級
  211. 3100  IF SW(NO)=-2 THEN *IN3  '##スピード
  212. 3110  IF SW(NO)=-1 THEN *IN4  '##ファイル名
  213. 3120  IF SW(NO)>=0 THEN *IN2  '##設定ON-OFF
  214. 3130 GOTO *IN0
  215. 3140 :
  216. 3150 *IN2
  217. 3160  IF A<>CHR$(&H1C) AND A<>CHR$(&H1D) THEN *IN1 
  218. 3170  SW(NO)=-(SW(NO)=0)
  219. 3180  IF CLASS=4 THEN SW(4)=0
  220. 3190  IF SW(1) THEN SW(4)=0 :SW(5)=1 :SW(6)=0 :SW(8)=0 :SW(9)=0
  221. 3200  IF SW(4) THEN SW(5)=0 :SW(6)=0 :SW(7)=0 :SW(8)=0 :SW(9)=0
  222. 3210  IF SW(7) THEN SW(5)=1 
  223. 3220  FOR I=1 TO W1C :GOSUB *SW :NEXT 
  224. 3230 GOTO *IN1
  225. 3240 *IN3
  226. 3250  SPEED=SPEED+(A=CHR$(&H1C))-(A=CHR$(&H1D))
  227. 3260  IF SPEED<1  THEN SPEED=40 
  228. 3270  IF SPEED>40 THEN SPEED=1
  229. 3280  A0=RIGHT$("  "+STR$(SPEED),3)
  230. 3290  AW1(NO)=A0 :COLOR 6 :LOCATE 27,4+NO :PRINT AW1(NO)
  231. 3300 GOTO *IN1
  232. 3310 *IN4
  233. 3320  IF A<>CHR$(13) AND A<>CHR$(&H1C) THEN *IN1
  234. 3330  COLOR 7 :LOCATE 27,4+NO
  235. 3340  LINE INPUT "",A0
  236. 3350  IF A0="" THEN *IN1
  237. 3360  COLOR 6 :LOCATE 27,4+NO
  238. 3370  IF LEN(A0)>12 THEN A0=LEFT$(A0,12)
  239. 3380  AW1(NO)=A0 :PRINT A0+SPACE$(13)
  240. 3390 GOTO *IN1
  241. 3400 *IN5
  242. 3410  CLASS=CLASS-(A=CHR$(&H1C))+(A=CHR$(&H1D))
  243. 3420  IF CLASS<0  THEN CLASS=4 
  244. 3430  IF CLASS>4 THEN CLASS=0
  245. 3440  A0=ACLASS(CLASS)
  246. 3450  AW1(NO)=A0 :COLOR 6 :LOCATE 27,4+NO :PRINT AW1(NO)
  247. 3460  IF CLASS<3 THEN SW(10)=1 ELSE SW(10)=0
  248. 3470  IF CLASS=4 THEN SW(1)=0 :SW(4)=0 :SW(11)=1 ELSE SW(11)=0
  249. 3480  FOR I=1 TO W1C :GOSUB *SW :NEXT 
  250. 3490 GOTO *IN1
  251. 3500 *IN6
  252. 3510  OTO=OTO+(A=CHR$(&H1C))*20-(A=CHR$(&H1D))*20
  253. 3520  IF OTO<400 THEN OTO=400 
  254. 3530  IF OTO>1100 THEN OTO=1100
  255. 3540  A0=RIGHT$("    "+STR$(OTO),4)
  256. 3550  AW1(NO)=A0 :COLOR 6 :LOCATE 27,4+NO :PRINT AW1(NO)
  257. 3560 GOTO *IN1
  258. 3570 :
  259. 3580 '-----
  260. 3590 *BACK
  261. 3600  IF TEST THEN 3710
  262. 3610  RESTORE 3610
  263. 3620  COLOR 5
  264. 3630   FOR I=1 TO 9
  265. 3640     READ A
  266. 3650     SYMBOL (430,240+I*20),A,1,1,4
  267. 3660   NEXT
  268. 3670  SYMBOL (390,270),"欧",1,1,5,,,7
  269. 3680  SYMBOL (390,300),"文",1,1,5,,,7
  270. 3690  SYMBOL (390,370),"和",1,1,5,,,7
  271. 3700  SYMBOL (390,400),"文",1,1,5,,,7
  272. 3710  LINE (580,258)-(600,258),PSET,4
  273. 3720  LINE (533,298)-(551,298),PSET,4
  274. 3730  LINE (533,357)-(565,357),PSET,4
  275. 3740  LINE (533,397)-(563,397),PSET,4
  276. 3750  LINE (420,255)-(420,440),PSET,%11
  277. 3760  LINE (380,345)-(630,345),PSET,%11
  278. 3770 RETURN
  279. 3780 DATA "本文始まり : HR HR BT"
  280. 3790 DATA " .... .-. .... .-. -...-"
  281. 3800 DATA "通信終了   : AR"
  282. 3810 DATA ".-.-."
  283. 3820 DATA " "
  284. 3830 DATA "本文始まり : ホレ"
  285. 3840 DATA "-..--- "
  286. 3850 DATA "通信終了   : ラタ"
  287. 3860 DATA "...-."
  288. 3870 :
  289. 3880 '-------
  290. 3890 *スタータ
  291. 3900  IF TEST THEN RETURN
  292. 3910  WHILE INKEY$<>"" :WEND
  293. 3920  SCREEN@ 2
  294. 3930  LOAD@ "QK.TIF"
  295. 3940  IF TEST THEN AT="Q" ELSE AT="CQ DE JG0QKR K"
  296. 3950  GOSUB *コンバート
  297. 3960  SPEED=4
  298. 3970  KEY(10) ON
  299. 3980   GOSUB *文字OUT1
  300. 3990  KEY(10) OFF
  301. 4000  IF INKEY$<>"" THEN GOSUB *S2
  302. 4010  SPEED=12
  303. 4020  SCREEN@ 0
  304. 4030 RETURN
  305. 4040 :
  306. 4050 *S2
  307. 4060  A=INPUT$(1) :X=210
  308. 4070  LINE (200,100)-(380,355),PSET,7,BF
  309. 4080  SYMBOL (X,105),"製作者：ＪＧ０ＱＫＲ",1,1,0,,,1
  310. 4090  SYMBOL (X,125),"協力者：ＪＧ０ＱＫＳ",1,1,0,,,1
  311. 4100  SYMBOL (X,145),"　　　：ＪＩ０ＦＬＳ",1,1,0,,,1
  312. 4110  SYMBOL (X,165),"Design：ゴルゴ小林",1,1,0,,,1
  313. 4120  SYMBOL (X,185),"Friend：ＪＧ０ＢＶＺ",1,1,0,,,1
  314. 4130  SYMBOL (X,205),"　　　：ＪＧ０ＰＭＵ",1,1,0,,,1
  315. 4140  SYMBOL (X,225),"　　　：ＪＧ０ＴＤＶ",1,1,0,,,1
  316. 4150  SYMBOL (X,245),"その他：ＪＧ０ＸＢＩ",1,1,0,,,1
  317. 4160  SYMBOL (X,265),"      ：のりＰ",1,1,0,,,1
  318. 4170  SYMBOL (X,285),"      ：まーすけ",1,1,0,,,1
  319. 4180  SYMBOL (X,310),"  1994/07/07",1,1,0,,,1 
  320. 4190  SYMBOL (X,330),"       by 尋燐･ルナ",1,1,0,,,1 
  321. 4200  A=INPUT$(1)
  322. 4210  FOR X=200 TO -50 STEP -5
  323. 4220   LINE (X,X-100)-(580-X,555-X),PSET,7,B
  324. 4230  NEXT
  325. 4240 RETURN
  326. 4250 :
  327. 4260 '-----
  328. 4270 *実行
  329. 4280  CLS
  330. 4290  AT=""
  331. 4300  IF CLASS<4 THEN AT="ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  332. 4310  IF CLASS=0 THEN AT="ｱｲｳｴｵｶｷｸｹｺｻｼｽｾｿﾀﾁﾂﾃﾄﾅﾆﾇﾈﾉﾊﾋﾌﾍﾎﾏﾐﾑﾒﾓﾔﾕﾖﾜｦﾝﾞﾟ-"
  333. 4320  IF SW(11) THEN AT=AT+"+-*/='(),.:･?｣"
  334. 4330  IF SW(10) THEN AT=AT+"1234567890"
  335. 4340  IF SW(4) THEN 4570
  336. 4350  IF SW(1)=0 THEN 4530
  337. 4360  IF CLASS=0 THEN 4460 
  338. 4370 '--欧文本番--
  339. 4380   ATS="HR HR < " :ATE=" >"     :'~BT  ~AR 
  340. 4390   IF CLASS=1 THEN CT=180 :I0=7
  341. 4400   IF CLASS=2 THEN CT=90  :I0=4
  342. 4410   IF CLASS=3 THEN CT=50  :I0=2
  343. 4420   GOSUB *文字列
  344. 4430   IF SW(5) THEN GOSUB *混ぜる
  345. 4440   AT=LEFT$(AT,CT)
  346. 4450  GOTO 4660
  347. 4460 '--和文本番-- 
  348. 4470   ATS="{ " :ATE=" }"     :'~ﾎﾚ  ~ﾗﾀ 
  349. 4480   CT=150
  350. 4490   GOSUB *文字列
  351. 4500   IF SW(5) THEN GOSUB *混ぜる
  352. 4510   AT=LEFT$(AT,CT)
  353. 4520  GOTO 4660
  354. 4530 '--練習--
  355. 4540   ATS="" :ATE=""
  356. 4550   IF SW(5) THEN GOSUB *混ぜる
  357. 4560  GOTO 4660
  358. 4570 '--TEST--
  359. 4580   IF CLASS=0 THEN CT=50
  360. 4590   IF CLASS=1 THEN CT=60
  361. 4600   IF CLASS=2 THEN CT=45
  362. 4610   IF CLASS=3 THEN CT=25
  363. 4620   GOSUB *文字列
  364. 4630   GOSUB *TEST
  365. 4640  RETURN
  366. 4650 :
  367. 4660 '--本流--
  368. 4670  IF SW(7)=0 THEN 4740          :'5文字
  369. 4680   A=AT :I0=LEN(A) :AT=""
  370. 4690   FOR I=1 TO I0
  371. 4700     IF ((I-1) MOD 5)=0 AND I<>1 THEN AT=AT+" " 
  372. 4710     AT=AT+MID$(A,I,1)
  373. 4720   NEXT
  374. 4730  GOTO 4820 
  375. 4740 : IF SW(1)=0 THEN 4820        :'本番 & not5文字
  376. 4750   A=AT :AT="" :I0=0
  377. 4760   FOR I=1 TO LEN(A)
  378. 4770     IF (INT(RND(1)*5)=3 AND I<>1) OR I0=>10 THEN AT=AT+" " :I0=0
  379. 4780     AT=AT+MID$(A,I,1)
  380. 4790     I0=I0+1
  381. 4800   NEXT 
  382. 4810 :
  383. 4820  ANS=AT
  384. 4830  AT=ATS+AT+ATE
  385. 4840 :
  386. 4850  IF TEST THEN PRINT AT
  387. 4860  GOSUB *コンバート
  388. 4870  F=0 :KEY(10) ON  :'強制終了
  389. 4880  COLOR 4 :PRINT "＊＊　それでは '";
  390. 4890  COLOR 6 :PRINT ACLASS(CLASS);
  391. 4900  COLOR 4 :PRINT "' を始めます。　途中'PF KEY10'を押すと中断します。  ＊＊"
  392. 4910  COLOR 7 :PRINT "・紙と鉛筆の用意は出来ましたか？"
  393. 4920  IF SW(1)=0 THEN 4970
  394. 4930  COLOR 5 :PRINT "本番と同じ形式です。"
  395. 4940  IF CLASS=0 THEN PRINT "始めの ホレ と、終わりの ラタ は書き取る必要がありません。" :GOTO 4960
  396. 4950  PRINT "始めの HR HR BT と、終わりの AR は書き取る必要がありません。"
  397. 4960  PRINT "終了後、直ちに鉛筆を置いてください。書き直しの時間はありません。"
  398. 4970  PRINT :COLOR 7
  399. 4980  IF POUT THEN PRINT "音声出力 & プリントアウト します。"
  400. 4990  PRINT "何かキーを押して下さい。２秒後に始まります。";
  401. 5000  IF SW(6) THEN PRINT "(１文字毎にウエイトが掛かります。)" ELSE PRINT ""
  402. 5010  WHILE INKEY$<>"" :WEND
  403. 5020  A=INPUT$(1) :PRINT "-Start!!-" :PRINT :WAIT 200
  404. 5030  IF SW(14) THEN GOSUB *声1 :WAIT 400
  405. 5040  TIME$="00:00:00"
  406. 5050 :
  407. 5060  IF SW(6) OR SW(8) OR SW(9) THEN GOSUB *文字OUT2 ELSE GOSUB *文字OUT1
  408. 5070 :
  409. 5080  KEY(10) OFF
  410. 5090  PRINT 
  411. 5100  COLOR 6 :PRINT "－ 終了いたしました。－" :COLOR 7
  412. 5110  PRINT "時間 ＝ ";RIGHT$(TIME$,4)
  413. 5120  IF SW(14) THEN WAIT 200 :GOSUB *声2
  414. 5130  A=ANS+"<"+SPACE$(250-LEN(ANS))
  415. 5140  PRINT "            0    .    1    .    2    .    3    .    4"
  416. 5150  PRINT "解答 ＝   0｜";LEFT$(A,40);"｜"
  417. 5160  PRINT "         40｜";MID$(A, 41,40);"｜"
  418. 5170  PRINT "         80｜";MID$(A, 81,40);"｜"
  419. 5180  PRINT "        120｜";MID$(A,121,40);"｜"
  420. 5190  PRINT "        160｜";MID$(A,161,40);"｜"
  421. 5200  PRINT "        200｜";MID$(A,201,40);"｜"
  422. 5210  PRINT "            0    .    1    .    2    .    3    .    4"
  423. 5220  IF SW(13) THEN GOSUB 5260
  424. 5230  WHILE INKEY$<>"" :WEND :A=INPUT$(1)
  425. 5240 RETURN
  426. 5250 :
  427. 5260 '---Printre OUT---
  428. 5270  LPRINT "   ｜0    .    1    .    2    .    3    .    4｜"
  429. 5280  LPRINT "  0｜ ";LEFT$(A,40)  ;"｜"
  430. 5290  LPRINT " 40｜ ";MID$(A, 41,40);"｜"
  431. 5300  LPRINT " 80｜ ";MID$(A, 81,40);"｜"
  432. 5310  LPRINT "120｜ ";MID$(A,121,40);"｜"
  433. 5320  LPRINT "160｜ ";MID$(A,161,40);"｜"
  434. 5330  LPRINT "200｜ ";MID$(A,201,40);"｜"
  435. 5340  LPRINT "   ｜0    .    1    .    2    .    3    .    4｜"
  436. 5350  LPRINT :LPRINT
  437. 5360 RETURN
  438. 5370 :
  439. 5380 '-----
  440. 5390 *文字列  '出題の元となるデータ作り AT,CT >AT
  441. 5400  A="" :I0=LEN(AT) :I1=CT
  442. 5410  IF I1>=I0 THEN A=A+AT :I1=I1-I0 :GOTO 5410
  443. 5420  IF I1 THEN A=A+LEFT$(AT,I1)
  444. 5430  AT=A
  445. 5440 RETURN
  446. 5450 :
  447. 5460 *TEST
  448. 5470  F=0
  449. 5480  COLOR 6 :PRINT "＊＊　只今モールス速度のテスト中！！　＊＊"
  450. 5490  COLOR 5 
  451. 5500   PRINT "・ ";ACLASS(CLASS);"  ";
  452. 5510   A=STR$(CT)
  453. 5520  PRINT A;"文字／分"
  454. 5530  A="    ･   " :FOR I=1 TO 6 :PRINT A;STR$(I); :NEXT :PRINT 
  455. 5540  COLOR 7 :PRINT AT
  456. 5550  GOSUB *コンバート
  457. 5560  TIME$="00:00:00"
  458. 5570  GOSUB *文字OUT1
  459. 5580  COLOR 4 :PRINT "掛かった時間 = ";TIME$
  460. 5590  COLOR 7 :PRINT :PRINT ">丁度１分が試験速度です。"
  461. 5600  PRINT ">機種によってマシン速度が違うので、各自速度を調整してください。"
  462. 5610  PRINT ">最終的には、１分以内の速度で本番用が書き取れれば良いでしょう。"
  463. 5620  PRINT :PRINT "何かキーを押すとメニューに戻ります。"
  464. 5630  WHILE INKEY$<>"" :WEND :A$=INPUT$(1)
  465. 5640 RETURN
  466. 5650 :
  467. 5660 '-------------
  468. 5670 *混ぜる
  469. 5680 FOR I0=1 TO 2
  470. 5690  FOR I=1 TO LEN(AT)
  471. 5700   I0=INT(RND(1)*LEN(AT))+1
  472. 5710   A=MID$(AT,I,1)  :A1=MID$(AT,I0,1)
  473. 5720   MID$(AT,I,1)=A1 :MID$(AT,I0,1)=A
  474. 5730  NEXT
  475. 5740 NEXT
  476. 5750 RETURN
  477. 5760 :
  478. 5770 '-----------
  479. 5780 :
  480. 5790 *コンバート
  481. 5800 MAX=LEN(AT)
  482. 5810   FOR I=1 TO MAX
  483. 5820     A=MID$(AT,I,1)
  484. 5830     AL(I)=AK(INSTR(ACOM,A))
  485. 5840   NEXT
  486. 5850 RETURN
  487. 5860 :
  488. 5870 *文字OUT1  :'ウエイト無し用
  489. 5880  FOR I=1 TO MAX
  490. 5890    FOR I0=1 TO LEN(AL(I))
  491. 5900      A=MID$(AL(I),I0,1)
  492. 5910      IF A="." THEN GOSUB *TEN
  493. 5920      IF A="-" THEN GOSUB *LNG
  494. 5930      IF A=" " THEN GOSUB *区切
  495. 5940      GOSUB *MAT
  496. 5950    NEXT
  497. 5960    GOSUB *SPC
  498. 5970    IF F THEN I=MAX
  499. 5980  NEXT
  500. 5990 RETURN
  501. 6000 :
  502. 6010 *文字OUT2  :'ウエイト有り
  503. 6020  FOR I=1 TO MAX
  504. 6030    A=MID$(ANS,I,1)
  505. 6040    IF A=" " THEN 6070
  506. 6050    IF SW(8) THEN PRINT A;"   "; ELSE PRINT ">   ";
  507. 6060    IF SW(9) THEN PRINT AL(I) ELSE PRINT 
  508. 6070    FOR I0=1 TO LEN(AL(I))
  509. 6080      A=MID$(AL(I),I0,1)
  510. 6090      IF A="." THEN GOSUB *TEN
  511. 6100      IF A="-" THEN GOSUB *LNG
  512. 6110      IF A=" " THEN GOSUB *区切
  513. 6120      GOSUB *MAT
  514. 6130    NEXT
  515. 6140    GOSUB *SPC
  516. 6150    IF SW(6) THEN WHILE INKEY$<>"" :WEND :A=INPUT$(1) :WAIT 100
  517. 6160    IF F THEN I=MAX
  518. 6170  NEXT
  519. 6180 RETURN
  520. 6190 :
  521. 6200 *TEN   :'  .
  522. 6210 BEEP 363523,300,OTO
  523. 6220 GOSUB *TIM
  524. 6230 BEEP 0
  525. 6240 RETURN
  526. 6250 :
  527. 6260 *LNG   :'  -
  528. 6270 BEEP 363523,300,OTO
  529. 6280 GOSUB *TIM
  530. 6290 GOSUB *TIM
  531. 6300 GOSUB *TIM
  532. 6310 BEEP 0
  533. 6320 RETURN
  534. 6330 :
  535. 6340 *KYU   :' - - 
  536. 6350 BEEP 0
  537. 6360 GOSUB *TIM
  538. 6370 BEEP 0
  539. 6380 RETURN
  540. 6390 :
  541. 6400 *SPC   :'  字と字間   必ず1け休符が入るため3-1=2
  542. 6410 GOSUB *TIM
  543. 6420 *区切  :'  区切り     必ず(*SPC+休符)*2が入るため7-(2+1)*3=1
  544. 6430 *MAT   :'  . と. の間 1
  545. 6440 GOSUB *TIM
  546. 6450 BEEP 0 :BEEP 0
  547. 6460 RETURN
  548. 6470 :
  549. 6480 *TIM  :'スピード調節
  550. 6490 WAIT SPEED
  551. 6500 RETURN
  552. 6510 :
  553. 6520 '----------------------
  554. 6530 *符号セット
  555. 6540 RESTORE 6620
  556. 6550 I=1 :ACOM=""
  557. 6560  READ AK(I),A
  558. 6570  ACOM=ACOM+A
  559. 6580  IF AK(I)<>"END" THEN I=I+1 :GOTO 6560
  560. 6590 RETURN
  561. 6600 :
  562. 6610 *M1
  563. 6620 DATA ".-"       ,"A
  564. 6630 DATA "-..."     ,"B
  565. 6640 DATA "-.-."     ,"C
  566. 6650 DATA "-.."      ,"D
  567. 6660 DATA "."        ,"E
  568. 6670 DATA "..-."     ,"F
  569. 6680 DATA "--."      ,"G
  570. 6690 DATA "...."     ,"H
  571. 6700 DATA ".."       ,"I
  572. 6710 DATA ".---"     ,"J
  573. 6720 DATA "-.-"      ,"K
  574. 6730 DATA ".-.."     ,"L
  575. 6740 DATA "--"       ,"M
  576. 6750 DATA "-."       ,"N
  577. 6760 DATA "---"      ,"O
  578. 6770 DATA ".--."     ,"P
  579. 6780 DATA "--.-"     ,"Q
  580. 6790 DATA ".-."      ,"R
  581. 6800 DATA "..."      ,"S
  582. 6810 DATA "-"        ,"T
  583. 6820 DATA "..-"      ,"U
  584. 6830 DATA "...-"     ,"V
  585. 6840 DATA ".--"      ,"W
  586. 6850 DATA "-..-"     ,"X
  587. 6860 DATA "-.--"     ,"Y
  588. 6870 DATA "--.."     ,"Z
  589. 6880 :
  590. 6890 *M2
  591. 6900 DATA "--.--"    ,"ｱ
  592. 6910 DATA ".-"       ,"ｲ
  593. 6920 DATA "..-"      ,"ｳ
  594. 6930 DATA "-.---"    ,"ｴ
  595. 6940 DATA ".-..."    ,"ｵ
  596. 6950 DATA ".-.."     ,"ｶ
  597. 6960 DATA "-.-.."    ,"ｷ
  598. 6970 DATA "...-"     ,"ｸ
  599. 6980 DATA "-.--"     ,"ｹ
  600. 6990 DATA "----"     ,"ｺ
  601. 7000 DATA "-.-.-"    ,"ｻ
  602. 7010 DATA "--.-."    ,"ｼ
  603. 7020 DATA "---.-"    ,"ｽ
  604. 7030 DATA ".---."    ,"ｾ
  605. 7040 DATA "---."     ,"ｿ
  606. 7050 DATA "-."       ,"ﾀ
  607. 7060 DATA "..-."     ,"ﾁ
  608. 7070 DATA ".--."     ,"ﾂ
  609. 7080 DATA ".-.--"    ,"ﾃ
  610. 7090 DATA "..-.."    ,"ﾄ
  611. 7100 :
  612. 7110 DATA ".-."      ,"ﾅ
  613. 7120 DATA "-.-."     ,"ﾆ
  614. 7130 DATA "...."     ,"ﾇ
  615. 7140 DATA "--.-"     ,"ﾈ
  616. 7150 DATA "..--"     ,"ﾉ
  617. 7160 DATA "-..."     ,"ﾊ
  618. 7170 DATA "--..-"    ,"ﾋ
  619. 7180 DATA "--.."     ,"ﾌ
  620. 7190 DATA "."        ,"ﾍ
  621. 7200 DATA "-.."      ,"ﾎ
  622. 7210 DATA "-..-"     ,"ﾏ
  623. 7220 DATA "..-.-"    ,"ﾐ
  624. 7230 DATA "-"        ,"ﾑ
  625. 7240 DATA "-...-"    ,"ﾒ
  626. 7250 DATA "-..-."    ,"ﾓ
  627. 7260 DATA ".--"      ,"ﾔ
  628. 7270 DATA "-..--"    ,"ﾕ
  629. 7280 DATA "--"       ,"ﾖ
  630. 7290 DATA "..."      ,"ﾗ
  631. 7300 DATA "--."      ,"ﾘ
  632. 7310 DATA "-.--."    ,"ﾙ
  633. 7320 DATA "---"      ,"ﾚ
  634. 7330 DATA ".-.-"     ,"ﾛ
  635. 7340 DATA "-.-"      ,"ﾜ
  636. 7350 DATA ".-..-"    ,"ｲ
  637. 7360 DATA ".--.."    ,"ｴ
  638. 7370 DATA ".---"     ,"ｦ
  639. 7380 DATA ".-.-."    ,"ﾝ
  640. 7390 :
  641. 7400 DATA ".."       ,"ﾞ"
  642. 7410 DATA "..--."    ,"ﾟ"
  643. 7420 DATA ".--.-"    ,"-"
  644. 7430 :
  645. 7440 DATA "-...-"    ,"<"  ' ~BT
  646. 7450 DATA ".-.-."    ,">"  ' ~AR
  647. 7460 DATA "-..--- "  ,"{"  ' ~ﾎﾚ
  648. 7470 DATA "...-."    ,"}"  ' ~ﾗﾀ
  649. 7480 DATA " "        ," "  'スペース
  650. 7490 :
  651. 7500 *M3
  652. 7510 DATA ".----"    ,"1
  653. 7520 DATA "..---"    ,"2
  654. 7530 DATA "...--"    ,"3
  655. 7540 DATA "....-"    ,"4
  656. 7550 DATA "....."    ,"5
  657. 7560 DATA "-...."    ,"6
  658. 7570 DATA "--..."    ,"7
  659. 7580 DATA "---.."    ,"8
  660. 7590 DATA "----."    ,"9
  661. 7600 DATA "-----"    ,"0
  662. 7610 :
  663. 7620 DATA ".-.-.-"   ,"･"  '終点
  664. 7630 DATA "--..--"   ,"."  '小読点
  665. 7640 DATA "---..."   ,":"  '重点又は除法の記号
  666. 7650 DATA "..--.."   ,"?"  '？
  667. 7660 DATA ".----."   ,","  '略符
  668. 7670 DATA "-....-"   ,"-"  '連続/横線/減算
  669. 7680 DATA "-.--."    ,"("
  670. 7690 DATA "-.--.-"   ,")"
  671. 7700 DATA "-...-"    ,"="
  672. 7710 DATA "-..-."    ,"/"
  673. 7720 DATA ".-.-."    ,"+"
  674. 7730 DATA "-..-"     ,"*"
  675. 7740 DATA ".-..-."   ,"'"  '引用符
  676. 7750 DATA ".-.-.."   ,"｣"  '段落
  677. 7760 :
  678. 7770 DATA "END"      ,""   '設定終了
  679. 7780 :
  680. 7790 '--------------
  681. 7800 *声1
  682. 7810  DIM PL(20000)
  683. 7820  LOAD@ "HAJI.SND",PL
  684. 7830  PCMPLAY PL,64
  685. 7840  ERASE PL
  686. 7850 RETURN
  687. 7860 :
  688. 7870 *声2
  689. 7880  DIM PL(20000)
  690. 7890  LOAD@ "ENPI.SND",PL
  691. 7900  PCMPLAY PL,64
  692. 7910  ERASE PL
  693. 7920 RETURN
  694. 7930 :
  695. 7940 '--------
  696. 7950 *メッセージ
  697. 7960 BEEP
  698. 7970 RESTORE 7970 :COLOR 5
  699. 7980 FOR I=1 TO 8 :READ A :LOCATE 44,I+8 :PRINT A :NEXT
  700. 7990 A=INPUT$(1)
  701. 8000 RETURN
  702. 8010 :
  703. 8020 DATA "＊　フレンド局へのメッセージ　＊"
  704. 8030 DATA "マー君  お誕生、おめでとう！
  705. 8040 DATA "FBな人生を送って下さい。"
  706. 8050 DATA "のりＰ/てるりん  お元気？"
  707. 8060 DATA "ＪＧ０ＱＫＳ　／ＢＶＺ /ゴルゴ小林君"
  708. 8070 DATA "２ｍの女王　ＰＭＵ局"
  709. 8080 DATA "今後とも宜しく！
  710. 8090 DATA "こちらはＪＧ０ＱＫＲ　尋燐･ルナ"
  711. 8100 :
  712. 8110 '--------
  713. 8120 *強制終了
  714. 8130  KEY(10) OFF
  715. 8140  BEEP 0 :F=1
  716. 8150 RETURN 
  717. 8160 :
  718. 8170 '-------------------------------------------------------
  719. 8180 *見本
  720. 8190  CLS :WIDTH 80,25 :COLOR 6
  721. 8200  PRINT "＊＊　モールス　見本　＊＊       1/欧文  2/和文  3/記号" 
  722. 8210  A=INPUT$(1) :COLOR 7
  723. 8220   IF A="1" THEN RESTORE *M1 :CT=26 :GOTO 8260 
  724. 8230   IF A="2" THEN RESTORE *M2 :CT=51 :GOTO 8260 
  725. 8240   IF A="3" THEN RESTORE *M3 :CT=24 :GOTO 8260
  726. 8250 RETURN
  727. 8260  I0=0 :I1=2
  728. 8270  FOR I=1 TO CT
  729. 8280   READ A,A0
  730. 8290   LOCATE I0,I1 :PRINT USING "&&  &      &  |  ";A0;A
  731. 8300   I1=I1+1 :IF I1>20 THEN I0=I0+20 :I1=2
  732. 8310  NEXT
  733. 8320  A=INPUT$(1)
  734. 8330 GOTO *見本
  735. 8340 :
  736. 8350 '----------------------------------------------------------
  737. 8360 *OMAKE
  738. 8370 CLS :COLOR 4
  739. 8380 PRINT "＃＃　　おまけ　コーナー　　by  尋燐･ルナ    ＃＃"
  740. 8390 PRINT "＃＃　　　　 1994/07/07       V3.02     　　 ＃＃"
  741. 8400 COLOR 7 :PRINT 
  742. 8410 PRINT "１．．全くモールスを知らない人へ"
  743. 8420 PRINT "２．．パソコン上と試験場での違い"
  744. 8430 PRINT "３．．練習していく手順"
  745. 8440 PRINT "４．．謝辞"
  746. 8450 PRINT "０．．戻る"
  747. 8460 PRINT 
  748. 8470 PRINT ">貴方はどれかを選ばなければならない！"
  749. 8480 PRINT ">さあ！どれにするかな？"
  750. 8490 A=INPUT$(1) :I=VAL(A)
  751. 8500  IF I=0 THEN RETURN
  752. 8510  IF I>4 THEN BEEP 363523,50,800 :COLOR 3 :PRINT ">ま、真面目にやりなさい！  いや。やってください。" :WAIT 300 :GOTO *OMAKE
  753. 8520 :
  754. 8530 ON I GOSUB *MENU1,*MENU2,*MENU3,*MENU4
  755. 8540 GOTO *OMAKE
  756. 8550 :
  757. 8560 *MENU1
  758. 8570 RESTORE 8570 :GOTO *表示
  759. 8580 DATA 4,"１．．全くモールスを知らない人へ（３級）"
  760. 8590 DATA 7,""
  761. 8600 DATA 7,"・試験には数字や記号は出ませんので（多分：出たらごめん！）"
  762. 8610 DATA 7,"　とにかく先ず英語Ａ－Ｚを覚えます。"
  763. 8620 DATA 7,"・最初は簡単な物　：ＳＯＳ　＝　...  ---  ...  トトト ツーツーツー トトト"
  764. 8630 DATA 7,"　　　　　　　　　：ＥＴ　　＝　.    -         ト  ツー"
  765. 8640 DATA 7,"                  ：ＨＩ　　＝　....   ..      トトトト   トト"
  766. 8650 DATA 7,"・イメージによる　：Ｑ　＝　--.-      Ｙ　＝　-.--     Ｘ　＝　-..-"
  767. 8660 DATA 7,"                  ：Ｚ　＝　--.."
  768. 8670 DATA 7,"　［文字では書きにくいが . を下げてあるのでイメージでは理解し易いと思う］"
  769. 8680 DATA 7,"・反対　　　　　　：Ｋ　＝　-.-       Ｒ　＝　.-."
  770. 8690 DATA 7,"                  ：Ａ　＝　.-        Ｎ　＝　-."
  771. 8700 DATA 7,"・似た物　　　　　：Ｕ　＝　..-       Ｖ　＝　...-"
  772. 8710 DATA 7,""
  773. 8720 DATA 7,"  等各自色々とやってみて下さい。"
  774. 8730 DATA 7," 　．を －より下に打って有るので結構覚えやすいと思います。"
  775. 8740 DATA 7,"  曖昧でもいいので５割位紙面上で覚えたら、このソフトを使って見てください。"
  776. 8750 DATA 7,""
  777. 8760 DATA 0,""
  778. 8770 :
  779. 8780 *MENU2
  780. 8790 RESTORE 8790 :GOTO *表示
  781. 8800 DATA 4,"２．．パソコン上と試験場での違い"
  782. 8810 DATA 7,""
  783. 8820 DATA 7,"・会場ではかなり音が反響してしまいます。（貴方が思っているより）"
  784. 8830 DATA 7,"  最悪音が二重に聞こえる場所も在ります。"
  785. 8840 DATA 7,"  早く会場に行き、なるべく前の方に座るようにしましょう！"
  786. 8850 DATA 7,"・最初にＡ－Ｚ迄１回鳴らしますのでその間に雰囲気を掴みます。"
  787. 8860 DATA 7,"・終了後すぐペンを置くように言われます。書き直す時間は有りません。"
  788. 8870 DATA 7,"・間違えは３点減点。減点は１０点迄です。"
  789. 8880 DATA 7,"  分からない／怪しい／ついていけない　と思ったらすぐその字は抜かしましょう。"
  790. 8890 DATA 7,"  １点減点のみですみます。"
  791. 8900 DATA 7,"・細かい事ですが音を正面で聞くか、右又は左で聞くかで怪しい文字の認識度が"
  792. 8910 DATA 7,"　違います。少しでも確実にしたいなら利き耳も考慮した方がいいかも。"
  793. 8920 DATA 7,"・練習の仕上げにバソコンから離れた所で書き取ることをしとくと良いでしょう！"
  794. 8930 DATA 7,"" ,7,""
  795. 8940 DATA 5,"      頑張って下さい。  by 尋燐･ルナ"
  796. 8950 DATA 0,""
  797. 8960 :
  798. 8970 *MENU3
  799. 8980 RESTORE 8980 :GOTO *表示
  800. 8990 DATA 4,"３．．練習していく手順
  801. 9000 DATA 7,""
  802. 9010 DATA 7,"・先ずＡ－Ｚを５割位とにかく覚えます。紙に書いたりして。"
  803. 9020 DATA 7,"　私流のイメージ、単純な文字のみで５割はいくでしょう。"
  804. 9030 DATA 7,"・Ａ－Ｚを順番にスロースピードorウエイトで（字、符号を表示しながら）"
  805. 9040 DATA 7,"・７割位覚えたらランダムにしてみます。"
  806. 9050 DATA 7,"・全部覚えたらもう字を表示させません。ウエイトは掛けてもよい。"
  807. 9060 DATA 7,"・慣れてきたらいよいよ書き取りします。ウエイトは外す。"
  808. 9070 DATA 7,"・後はスピードを上げたり本番用にしたりいろいろやってみましょう"
  809. 9080 DATA 7,"・３級では数字は出ない筈ですが、２級では必ずではないが出題されます。"
  810. 9090 DATA 7,"  泣く人が多いので勉強しておいてください。"
  811. 9100 DATA 7,"・記号は１級で出るかもしれません。しかし殆ど実戦用に作った物です。"
  812. 9110 DATA 7,"・仕上げはかなり離れた所にて書き取りします。"
  813. 9120 DATA 7,"" ,7,""
  814. 9130 DATA 6,"    実際はかなり速いスピードでＱＳＯしているのです。"
  815. 9140 DATA 6,"        例え１級のスピードでもかなり遅いのですよ。
  816. 9150 DATA 7,""
  817. 9160 DATA 5,"      頑張って下さい。  by 尋燐･ルナ"
  818. 9170 DATA 0,""
  819. 9180 :
  820. 9190 *MENU4
  821. 9200 RESTORE 9200 :GOTO *表示
  822. 9210 DATA 4,"４．．謝辞
  823. 9220 DATA 7,""
  824. 9230 DATA 6,"　　是を作るにあたり協力してくれた方々に"
  825. 9240 DATA 6,"                  この場を借りて御礼申し上げます。"
  826. 9250 DATA 7,"
  827. 9260 DATA 7,"　　ＪＧ０ＱＫＳ　　　ＪＧ０ＰＭＵ　　　ＪＦ０ＫＱＦ"
  828. 9270 DATA 7,"　　ＪＧ０ＰＭＵ　　　ＪＧ０ＴＤＶ"
  829. 9280 DATA 7," "
  830. 9290 DATA 7,"　　ＪＧ０ＸＢＩ　　　ＪＩ０ＦＬＳ"
  831. 9300 DATA 7," "
  832. 9310 DATA 7,"    のりＰ　　　マースケ"
  833. 9320 DATA 7," "
  834. 9330 DATA 7,"　そして"
  835. 9340 DATA 7,"    ゴルゴ･小林  様 
  836. 9350 DATA 7," "
  837. 9360 DATA 6,"     いろいろと有り難うございました。"
  838. 9370 DATA 6,"                   ＪＧ０ＱＫＲ　　尋燐･ルナ"
  839. 9380 DATA 0,""
  840. 9390 :
  841. 9400 *表示
  842. 9410 CLS
  843. 9420 READ I,A
  844. 9430   WHILE I>0
  845. 9440     COLOR I
  846. 9450     PRINT A
  847. 9460     READ I,A
  848. 9470   WEND
  849. 9480 A=INPUT$(1)
  850. 9490 RETURN
  851. 9500 :
  852. 9510 '---------------  E  N  D  ---------------------
  853.